图形按钮图片生成器工具源码

.版本 2
.支持库 spec

.子程序 画图形按钮
.参数 父画板, 画板
.参数 按钮宽度, 整数型
.参数 按钮高度, 整数型
.参数 按钮文字, 文本型
.参数 按钮文字大小, 整数型
.参数 按钮文字颜色, 整数型
.参数 按钮边框颜色, 整数型
.参数 按钮渐变色1, 整数型
.参数 按钮渐变色2, 整数型
.参数 按钮类型, 整数型, , 0：矩形；1：圆角
.局部变量 局部_字宽, 整数型
.局部变量 局部_字高, 整数型

父画板.画板背景色 ＝ #品红
父画板.移动 (, , 按钮宽度, 按钮高度)
延迟 (10)
' 调整画板的高宽度，避免背景色晃眼睛
父画板.清除 (0, 0, 父画板.宽度, 父画板.高度)
' 清除图案
父画板.画笔颜色 ＝ 到整数 (按钮边框颜色)
父画板.字体.字体大小 ＝ 按钮文字大小
' 设置画笔颜色
.如果真 (按钮类型 ＝ 0)
    ' 矩形边框
    父画板.画矩形 (0, 0, 按钮宽度, 按钮高度)
    父画板.画渐变矩形 (1, 1, 按钮宽度 － 2, 按钮高度 － 2, C_渐变方向, 按钮渐变色1, 按钮渐变色2)
.如果真结束
.如果真 (按钮类型 ＝ 1)
    ' 圆角边框
    父画板.画圆角矩形 (0, 0, 按钮宽度, 按钮高度, 5, 5)
    父画板.画渐变矩形 (1, 2, 按钮宽度 － 2, 按钮高度 － 4, C_渐变方向, 按钮渐变色1, 按钮渐变色2)
    父画板.画笔颜色 ＝ 按钮渐变色1
    父画板.画直线 (2, 1, 按钮宽度 － 2, 1)
    父画板.画笔颜色 ＝ 按钮渐变色2
    父画板.画直线 (2, 按钮高度 － 2, 按钮宽度 － 2, 按钮高度 － 2)
.如果真结束
父画板.文本颜色 ＝ 按钮文字颜色
局部_字宽 ＝ 父画板.取宽度 (按钮文字)
局部_字高 ＝ 父画板.取高度 (按钮文字)
父画板.定位写出 (按钮宽度 ÷ 2 － 局部_字宽 ÷ 2, 按钮高度 ÷ 2 － 局部_字高 ÷ 2, 按钮文字)
' 1、从上到下； 2、从左到右； 3、从左上到右下； 4、从右上到左下； 5、从下到上； 6、从右到左； 7、从右下到左上； 8、从左下到右上。 如果本参数被省略，默认为“#从左到右”

@wshsys