易语言调整屏幕亮度源码

资源介绍：

易语言调整屏幕亮度源码例程程序调用API函数实现屏幕亮度的调节。

资源作者：

三叶资源网

资源界面：

.版本 2

.程序集 窗口程序集1
.程序集变量 hDC, 整数型
.程序集变量 old, 短整数型, , "256,3"

.子程序 __启动窗口_创建完毕
.局部变量 ret, 逻辑型

.如果真 (打开事件同步对象 (2031619, 假, “rjhmj”) ≠ 0)
    _启动窗口.激活 ()
    结束 ()
.如果真结束
创建事件同步对象 (0, 假, 假, “rjhmj”)
hDC ＝ GetDC (GetDesktopWindow ())
ret ＝ GetDeviceGammaRamp (hDC, old)

.子程序 __启动窗口_将被销毁

SetBrightness (0)
ReleaseDC (GetDesktopWindow (), hDC)

.子程序 _滑块条1_位置被改变

SetBrightness (滑块条1.位置 － 50)

.子程序 SetBrightness
.参数 intRGB, 整数型
.局部变量 i, 整数型
.局部变量 ii, 整数型
.局部变量 new, 短整数型, , "256,3"

.计次循环首 (256, i)
    .计次循环首 (3, ii)
        .判断开始 (intRGB ＜ 0)
            new [i] [ii] ＝ ConvToSignedValue (ConvToUnSignedValue (old [i] [ii]) × (100 － 取绝对值 (intRGB)) ÷ 100)
        .判断 (intRGB ＝ 0)
            new [i] [ii] ＝ old [i] [ii]
        .默认
            new [i] [ii] ＝ ConvToSignedValue (65535 － (65535 － ConvToUnSignedValue (old [i] [ii])) × (100 － intRGB) ÷ 100)
        .判断结束

    .计次循环尾 ()
.计次循环尾 ()
SetDeviceGammaRamp (hDC, new)

.子程序 ConvToSignedValue, 短整数型
.参数 lngValue, 短整数型

返回 (选择 (lngValue ≤ 32767, lngValue, lngValue － 65535))

.子程序 ConvToUnSignedValue, 整数型
.参数 intValue, 短整数型

返回 (选择 (intValue ≥ 0, intValue, intValue ＋ 65535))

.子程序 _按钮确定_被单击

_启动窗口.位置 ＝ 2

.子程序 __启动窗口_位置被改变

.如果真 (_启动窗口.位置 ＝ 2)
    _启动窗口.可视 ＝ 假
    置托盘图标 (#托盘, )
.如果真结束


.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型

.如果真 (操作类型 ＝ #单击左键)
    置托盘图标 (, )
    _启动窗口.可视 ＝ 真
.如果真结束
.如果真 (操作类型 ＝ #单击右键)
    弹出菜单 (隐藏, , )
.如果真结束


.子程序 _退出_被选择

__启动窗口_将被销毁 ()
结束 ()

资源下载：