易语言验证码二值化/清除杂点算法源码

易语言验证码二值化/清除杂点算法源码，源码内含有图片二值化,清楚杂点,反色等算法与原理

二值化模式不同论坛现有的源码.自定义阀值 根据RGB二值化.

论坛上也没清除杂点处理的源码.

.版本 2
.支持库 internet
.支持库 shell
.支持库 BmpOperate

.程序集 窗口程序集1

.子程序 _按钮1_被单击

画板1.底图 ＝ HTTP读文件 (“http://www.u148.net/ajax/vimg”)

.子程序 _按钮5_被单击

写到文件 (取特定目录 (3) ＋ “” ＋ 到文本 (取现行时间 ()) ＋ “.jpg”, 画板2.取图片 (, ))

.子程序 _按钮2_被单击

画板2.底图 ＝ 二值化处理 (画板1.取图片 (, ), 到数值 (编辑框1.内容))

.子程序 _按钮3_被单击

画板2.底图 ＝ 反色处理 (画板2.取图片 (, ))

.子程序 _按钮4_被单击

画板2.底图 ＝ 清除杂点 (画板2.取图片 (, ), 到数值 (编辑框2.内容))

.子程序 二值化处理, 字节集
.参数 图片, 字节集
.参数 二值化值, 整数型
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 RGB, 字节集
.局部变量 颜色值, 整数型

位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
    .计次循环首 (位图.取宽度 (), x)
        RGB ＝ 到字节集 (位图.取某点颜色 (x － 1, y － 1))
        颜色值 ＝ (RGB [1] ＋ RGB [2] ＋ RGB [3]) ÷ 3
        .如果 (二值化值 ＜ 颜色值)
            位图.置某点颜色 (x － 1, y － 1, #白色)
        .否则
            位图.置某点颜色 (x － 1, y － 1, #黑色)
        .如果结束

    .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())

.子程序 清除杂点, 字节集
.参数 图片, 字节集, , 二值化后的图片
.参数 清除强度, 整数型, 可空, 默认为1
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 x_, 整数型
.局部变量 y_, 整数型
.局部变量 i, 整数型
.局部变量 a, 整数型

.如果真 (是否为空 (清除强度))
    清除强度 ＝ 1
.如果真结束
位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
    .计次循环首 (位图.取宽度 (), x)
        .如果真 (位图.取某点颜色 (x － 1, y － 1) ＝ #黑色)
            a ＝ 0
            .计次循环首 (8, i)
                x_ ＝ 多项选择 (i, 0, 1, 1, 1, 0, -1, -1, -1)
                y_ ＝ 多项选择 (i, -1, -1, 0, 1, 1, 1, 0, -1)
                .如果真 (位图.取某点颜色 (x － 1 － x_, y － 1 － y_) ＝ #黑色)
                    a ＝ a ＋ 1
                .如果真结束

            .计次循环尾 ()
            .如果真 (a ≤ 清除强度)
                位图.置某点颜色 (x － 1, y － 1, #白色)
            .如果真结束

        .如果真结束

    .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())

.子程序 反色处理, 字节集
.参数 图片, 字节集
.局部变量 位图, 位图
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 RGB, 字节集

位图.载入数据 (图片)
.计次循环首 (位图.取高度 (), y)
    .计次循环首 (位图.取宽度 (), x)
        RGB ＝ 到字节集 (位图.取某点颜色 (x － 1, y － 1))
        位图.置某点颜色 (x － 1, y － 1, 取颜色值 (255 － RGB [1], 255 － RGB [2], 255 － RGB [3]))
    .计次循环尾 ()
.计次循环尾 ()
返回 (位图.取位图数据 ())

@Mr.Yang