易语言POST例程 天气查询源码

.版本 2
.支持库 xplib
.支持库 spec
.支持库 EThread

.程序集 窗口程序集_启动窗口

.子程序 __启动窗口_创建完毕

XP风格 (1)

.子程序 GET天气
.局部变量 getaddress, 文本型
.局部变量 returndata, 文本型
.局部变量 txttoabc, 文本型
.局部变量 city, 文本型
.局部变量 weather, 文本型

按钮_查询.标题 ＝ “查询中...”
txttoabc ＝ 文本_转拼音 (删首尾空 (编辑框_天气城市.内容), )  ' 大家可以想一下，这里为什么要转成拼音。
getaddress ＝ “http://www.haotq.com/d_” ＋ txttoabc ＋ “.html”  ' 这是GET数据包的地址
returndata ＝ 到文本 (网页_访问_对象 (getaddress, 0, , , , ))
调试输出 (returndata)  ' 有兴趣的朋友，可以多看一下返回文本，里面有很多可用的信息，自己可以再编写一下。
调试输出 (txttoabc)
city ＝ 文本_取出中间文本 (returndata, #Titleleft, #Titleright, , 真)  ' 取出文本中间要用的信息。
weather ＝ 文本_取出中间文本 (returndata, #weather0, #weather1)
.如果 (寻找文本 (returndata, “出错了，页面不存在！”, , 假) ＝ -1)
    编辑框_天气输出.文本颜色 ＝ #蓝色
    编辑框_天气输出.内容 ＝ 文本_删首尾空 (city ＋ #换行符 ＋ “更新时间:” ＋ 到文本 (取现行时间 ()) ＋ #换行符 ＋ 文本_删除空行 (文本_删首尾空 (文本_替换 (weather, , , , “&nbsp;”, “”, “<br>”, #换行符, #weatherempty, “”, #dayempty, “”))) ＋ #换行符)
    按钮_查询.标题 ＝ “查询”
.否则
    信息框 (“无该城市，请重新输入”, 0, “错误”)
    编辑框_天气城市.内容 ＝ “”
    编辑框_天气城市.获取焦点 ()
    按钮_查询.标题 ＝ “查询”
.如果结束


.子程序 _按钮_查询_被单击

.如果 (编辑框_天气城市.内容 ≠ “”)
    启动线程 (&GET天气, , )
.否则
    信息框 (“请输入要查询的城市”, 0, )
    编辑框_天气城市.获取焦点 ()
.如果结束


.子程序 _按钮_更新天气_被单击

启动线程 (&GET天气, , )

.子程序 _按钮_分享天气_被单击

.如果 (置剪辑板文本 (编辑框_天气输出.内容) ＝ 真)
    信息框 (“成功复制到粘贴板”, #信息图标, “提示”)
.否则
    信息框 (“复制失败”, #错误图标, “提示”)
.如果结束


.子程序 _编辑框_天气城市_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型

.如果真 (键代码 ＝ #回车键)
    _按钮_查询_被单击 ()
.如果真结束

@易语言例程