易语言多线程adsl拨号演示例程

资源介绍：

源码调用了精易模块。

.版本 2
.支持库 iext
.支持库 EThread
.支持库 spec
.支持库 internet

.程序集 窗口程序集_启动窗口

.子程序 __启动窗口_创建完毕

许可证 ＝ 线程_创建许可证 ()  ' 首先要创建一个许可证，否则运行一运行，马上就闪退...死翘翘...
许可证2 ＝ 线程_创建许可证 ()  ' 首先要创建一个许可证，否则运行一运行，马上就闪退...死翘翘...
初始化 ()

.子程序 初始化

.计次循环首 (100, )
    超级列表框1.插入表项 (, , , , , )
    超级列表框1.置标题 (超级列表框1.取表项数 () － 1, 0, 到文本 (超级列表框1.取表项数 ()))
    超级列表框1.置标题 (超级列表框1.取表项数 () － 1, 1, 文本_取随机数字 (2))
    超级列表框1.置标题 (超级列表框1.取表项数 () － 1, 2, 文本_取随机数字 (2))
.计次循环尾 ()

.子程序 _按钮1_被单击

启动线程 (&线程池, , )

.子程序 线程池
.局部变量 int, 整数型
.局部变量 adsl, ADSL拨号类
.局部变量 ADSL_int, 整数型, 静态, , 静态的意思，如果大家不懂，可以到子程序10，自己测试结果，如果不是傻子，一看就明白了...

.计次循环首 (超级列表框1.取表项数 (), int)
    超级列表框1.置标题 (int － 1, 3, “登陆...”)
    启动线程 (&开始线程, int, )
    调试输出 (线程控制ID)
    .判断循环首 (线程控制ID ≥ 到整数 (编辑框1.内容))
        程序_延时 (3000)
    .判断循环尾 ()
    .如果真 (到整数 (编辑框2.内容) ＞ 0)  ' 当登陆几个拨号大于0的时候，对程序运行次数进行计次统计.....
        ADSL_int ＝ ADSL_int ＋ 1
        .如果真 (ADSL_int ≥ 到整数 (编辑框2.内容))  ' 当adsl计次统计达成设置的[登陆几个拨号]参数协议，立马执行，拨号事件......
            挂断 ()
            延迟 (200)  ' 为了怕出错,,,,加一个延迟....
            adsl.拨号 (编辑框5.内容, 编辑框3.内容, 编辑框4.内容)
            .判断循环首 (是否已在线 () ＝ 假)  ' 加一个是否已经正常联网判断，免得网络还没通，就执行继续登陆事件了......
            .判断循环尾 ()
            ADSL_int ＝ 0  ' 拨号全部结束后，不要忘记把 adsl计次统计给复原为0，否则就还会继续拨号了惹...........

        .如果真结束

    .如果真结束

.计次循环尾 ()


.子程序 开始线程
.参数 int, 整数型
.局部变量 帐号, 文本型
.局部变量 密码, 文本型
.局部变量 str, 文本型, , , 为了给你们演示，做一个虚拟pst登陆吧...
.局部变量 adsl, ADSL拨号类

.如果真 (到整数 (编辑框2.内容) ＞ 0)  ' 设置的[当登陆几个拨号]大于0的时候，发现adsl断开，立马陷入循环... ...
    .判断循环首 (adsl.取连接状态 (编辑框5.内容) ＝ 假)

    .判断循环尾 ()
.如果真结束

线程_进入许可区 (许可证)
线程控制ID ＝ 线程控制ID ＋ 1
线程_退出许可区 (许可证)
线程_进入许可区 (许可证2)
帐号 ＝ 超级列表框1.取标题 (int － 1, 1)
密码 ＝ 超级列表框1.取标题 (int － 1, 2)

str ＝ 网页_访问S (“http://bbs.125.la/”, 1, “uer=” ＋ 编码_URL编码 (帐号, , 真) ＋ “&pass=” ＋ 密码)  ' 为了给你们演示，做一个虚拟pst登陆吧...

.判断开始 (寻找文本 (str, “登陆成功”, , 假) ≠ -1)
    超级列表框1.置标题 (int － 1, 3, “登陆成功”)
.默认
    超级列表框1.置标题 (int － 1, 3, “登陆失败”)
.判断结束

超级列表框1.置标题 (int － 1, 4, 到文本 (到数值 (帐号) ＋ 到数值 (密码)))

程序_延时 (2000)  ' 这个可以删除掉，只是为了演示能够看得清除一些，让速度慢点... ...
线程_退出许可区 (许可证2)

线程_进入许可区 (许可证)
线程控制ID ＝ 线程控制ID － 1
线程_退出许可区 (许可证)


.子程序 子程序10
.局部变量 静态变量, 整数型, 静态
.局部变量 非静态变量, 整数型

静态变量 ＝ 静态变量 ＋ 1
非静态变量 ＝ 非静态变量 ＋ 1
调试输出 (“静态变量演示结果：”, 静态变量)
调试输出 (“非静态变量演示结果：”, 非静态变量)
调试输出 (“-------------------------------------------------”)

.子程序 _按钮2_被单击

子程序10 ()
子程序10 ()
信息框 (“看调式输出，静态第二次输出就是2   非静态第二次输出就是1  ”, 0, , )

资源作者：

@ｑｑ516290517

资源下载：