高级表格属性框类 v1.3

原帖是高表扩展类，其中附带了属性框功能，这次把其中的属性框单独摘了出来，方便大家使用。

V1.3

------------

1.修复分组收缩时嵌入的组件未能隐藏的问题。

@Life

.版本 2
.支持库 eGrid
.支持库 iext

.程序集 窗口程序集_窗口1
.程序集变量 集_属性框, 属性类

.子程序 _窗口1_创建完毕

_属性框初始化 ()

.子程序 _属性框初始化
.局部变量 局变量_父ID, 整数型
.局部变量 局变量_子ID, 整数型

高表.置列宽 (1, 130)  ' 调节属性框标题列宽度

集_属性框.初始化 (按钮_下拉专用.取窗口句柄 (), 高表, #银白, #黑色, #银白, 取颜色值 (70, 70, 70), 取颜色值 (70, 70, 70), 30)
集_属性框.添加弹出组件 (列表框1.取窗口句柄 (), 真, #自定义标记_下拉列表动态填充)
集_属性框.添加弹出组件 (树型框1.取窗口句柄 (), 真, 2)
集_属性框.添加弹出组件 (月历1.取窗口句柄 (), 假, 3)

' ---------------------
局变量_父ID ＝ 集_属性框.添加项目 (真, 0, “首分组”, 假, 假, , , , )
集_属性框.添加项目 (假, 局变量_父ID, “下拉列表”, 真, 真, , , #自定义标记_下拉列表, , , &_动态列表, #自定义标记_下拉列表动态填充)
高表.置数据 (1, 2, #表格常量.文本型, “真”)

集_属性框.添加项目 (假, 局变量_父ID, “树型框列表”, 假, 真, , , #自定义标记_下拉树, , )

集_属性框.添加项目 (假, 局变量_父ID, “嵌入调节器”, 真, 假, , , #自定义标记_调节器, , )
高表.置数据 (3, 2, #表格常量.文本型, “4”)
集_属性框.嵌入组件 (3, 2, 调节器1.取窗口句柄 (), 真, #右边框, )

集_属性框.添加项目 (假, 局变量_父ID, “日历框”, 假, 真, , , #自定义标记_月历)
' ---------------------
局变量_父ID ＝ 集_属性框.添加项目 (真, 局变量_父ID, “子分组”, 假, 假, , , )
集_属性框.添加项目 (假, 局变量_父ID, “颜色对话框”, 假, 真, , , #自定义标记_颜色)
' 颜色选择器不能使用“添加弹出组件( )”，为了效果，只能使用“嵌入组件( )”，设置可视为假
集_属性框.嵌入组件 (6, 2, 颜色选择器1.取窗口句柄 (), 假, #左边框, )

集_属性框.添加项目 (假, 局变量_父ID, “打开对话框”, 假, 真, , , #自定义标记_打开)
集_属性框.添加项目 (假, 局变量_父ID, “保存对话框”, 假, 真, , , #自定义标记_保存)
集_属性框.添加项目 (假, 局变量_父ID, “浏览对话框”, 假, 真, , , #自定义标记_浏览)
集_属性框.添加项目 (假, 局变量_父ID, “字体对话框”, 假, 真, , , #自定义标记_字体)

' ---------------------
局变量_父ID ＝ 集_属性框.添加项目 (真, 0, “分组演示”, 假, 假, , , , , )
集_属性框.添加项目 (假, 局变量_父ID, “项目1”, 假, 真, “OK”, 24, )
集_属性框.添加项目 (假, 局变量_父ID, “项目2”, 假, 真, “OK”, 24, )
集_属性框.添加项目 (假, 局变量_父ID, “项目3”, 假, 真, “OK”, 24, )
' ---------------------
局变量_父ID ＝ 集_属性框.添加项目 (真, 局变量_父ID, “子分组演示”, 假, 假, , , , )
集_属性框.添加项目 (假, 局变量_父ID, “项目4”, 假, 真, “OK”, 24, )
' ---------------------
局变量_父ID ＝ 集_属性框.添加项目 (真, 0, “分组演示”, 假, 假, , , , , )
局变量_子ID ＝ 集_属性框.添加项目 (假, 局变量_父ID, “项目5”, 真, 真, “OK”, 24, )
集_属性框.添加项目 (假, 局变量_子ID, “子项目6”, 假, 真, , , )

局变量_子ID ＝ 集_属性框.添加项目 (假, 局变量_父ID, “项目7”, 真, 真, “OK”, 24, )
集_属性框.添加项目 (假, 局变量_子ID, “子项目8”, 假, 真, , , )


.子程序 _动态列表
.参数 参数_行号, 整数型
.参数 参数_列号, 整数型
.参数 参数_项目内容, 整数型
.局部变量 Var_Text, 文本型

Var_Text ＝ 指针到文本 (参数_项目内容)
列表框1.清空 ()
列表框1.加入项目 (“动态A”, 1)
列表框1.加入项目 (“动态B”, 2)
列表框1.加入项目 (“动态C”, 3)
列表框1.加入项目 (“动态D”, 4)

.子程序 _高表_可否被编辑, 逻辑型, , 必须本子程序，否则不能正常编辑

返回 (集_属性框.同步事件_可否被编辑 ())

.子程序 _按钮_下拉专用_被单击, , , 必须本子程序，否则下拉按钮无响应。
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集
.局部变量 Var_Index, 整数型

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
.判断开始 (Var_Value ＝ #自定义标记_下拉列表)
    列表框1.清空 ()
    列表框1.加入项目 (“选项A”, 1)
    列表框1.加入项目 (“选项B”, 2)
    列表框1.加入项目 (“选项C”, 3)
    集_属性框.弹出组件 (列表框1.取窗口句柄 ())

.判断 (Var_Value ＝ #自定义标记_下拉树)
    树型框1.清空 ()
    Var_Index ＝ 树型框1.加入项目 (, “Top”, , , , , )
    树型框1.加入项目 (Var_Index, “ssd”, , , , , )
    树型框1.加入项目 (Var_Index, “123”, , , , , )
    树型框1.加入项目 (Var_Index, “456”, , , , , )
    树型框1.扩展 (Var_Index)
    集_属性框.弹出组件 (树型框1.取窗口句柄 ())
.判断 (Var_Value ＝ #自定义标记_颜色)
    颜色选择器1.颜色 ＝ 高表.取单元格背景颜色 (Var_Row, Var_Column)
    颜色选择器1.发送信息 (514, 0, 0)

.判断 (Var_Value ＝ #自定义标记_打开)
    通用对话框1.类型 ＝ 0
    通用对话框1.过滤器 ＝ “所有文件(*.*)|*.*”
    .如果真 (通用对话框1.打开 ())
        高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, _取扩展名 (通用对话框1.文件名))
    .如果真结束

.判断 (Var_Value ＝ #自定义标记_保存)
    通用对话框1.类型 ＝ 1
    通用对话框1.过滤器 ＝ “所有文件(*.*)|*.*”
    .如果真 (通用对话框1.打开 ())
        高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, _取扩展名 (通用对话框1.文件名))
    .如果真结束

.判断 (Var_Value ＝ #自定义标记_浏览)
    高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, _浏览文件夹 ())
.判断 (Var_Value ＝ #自定义标记_字体)
    通用对话框1.类型 ＝ 2
    .如果真 (通用对话框1.打开 ())
        高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 通用对话框1.字体名称)
    .如果真结束

.判断 (Var_Value ＝ #自定义标记_月历)
    集_属性框.弹出组件 (月历1.取窗口句柄 ())
.默认

.判断结束


.子程序 _列表框1_双击选择, , , 增加了该弹出组件，就要响应触发事件。
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 列表框1.取项目文本 (列表框1.现行选中项))
集_属性框.收起组件 ()

.子程序 _树型框1_双击项目, , , 增加了该弹出组件，就要响应触发事件。
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 树型框1.取项目文本 (树型框1.现行选中项))
集_属性框.收起组件 ()

.子程序 _调节器1_调节钮被按下, , , 嵌入了该组件，就要响应触发事件。
.参数 按钮值, 整数型
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 到数值 (高表.取数据 (Var_Row, Var_Column)) ＋ 按钮值)

.子程序 _颜色选择器1_颜色被改变, , , 嵌入了该组件，就要响应触发事件。
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集
.局部变量 Var_Colour, 字节集

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
高表.置单元格背景颜色 (Var_Row, Var_Column, Var_Row, Var_Column, 颜色选择器1.颜色)
Var_Colour ＝ 到字节集 (颜色选择器1.颜色)
高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 到文本 (Var_Colour [1]) ＋ “,” ＋ 到文本 (Var_Colour [2]) ＋ “,” ＋ 到文本 (Var_Colour [3]))

.子程序 _月历1_选择日期被改变, , , 增加了该弹出组件，就要响应触发事件。
.局部变量 Var_Row, 整数型
.局部变量 Var_Column, 整数型
.局部变量 Var_Pos, Rect
.局部变量 Var_Value, 双精度小数型
.局部变量 Var_Note, 文本型
.局部变量 Var_Data, 字节集

集_属性框.取位置信息 (Var_Row, Var_Column, Var_Pos, Var_Value, Var_Note, Var_Data)
高表.置数据 (Var_Row, Var_Column, #表格常量.文本型, 时间到文本 (月历1.首选择日, #日期部分))
集_属性框.收起组件 ()