易语言监视USB口插入拔出源码

监视USB口，易语言监视USB口插入拔出源码。

@易语言入门教程

.版本 2

.程序集 窗口程序集1
.程序集变量 a, 子程序指针

.子程序 __启动窗口_创建完毕

a ＝ SetWindowLong (_启动窗口.取窗口句柄 (), -4, &MsgProc)
' 弹出
' * 537,7,0
' * 537,7,0
' * 537,7,0
' * 537,32772,1244672

' 插入
' 537,7,0
' * 537,7,0
' * 537,7,0
' * 537,7,0
' * 537,7,0
' * 537,32768,1244672
' * 537,7,0


.子程序 MsgProc, 整数型
.参数 hwnd, 整数型
.参数 msg, 整数型
.参数 wp, 整数型, , ' 本源码来自三叶资源网(www.sanye.cx)
.参数 lp, 整数型
.局部变量 val, PDEV_BROADCAST_VOLUME
.局部变量 i, 整数型
.局部变量 mask, 整数型

.判断开始 (msg ＝ 537)
    .判断开始 (wp ＝ #DBT_DEVICERARRIVAL)  ' 插入设备
        复制结构体 (val, lp, 14)
        .如果真 (val.dbcv_devicetype ＝ #DBT_DEVTYP_VOLUME)
            mask ＝ val.dbcv_unitmask
            .变量循环首 (0, 25, 1, i)
                .如果真 (位与 (mask, 1) ＝ 1)
                    跳出循环 ()
                .如果真结束
                mask ＝ 右移 (mask, 1)
            .变量循环尾 ()
            编辑框1.加入文本 (“USB磁盘被插入，盘符:” ＋ 字符 (65 ＋ i) ＋ #换行符)
            检测 (字符 (65 ＋ i))
        .如果真结束
        ' 本源码来自三叶资源网(www.sanye.cx)
    .判断 (wp ＝ #DBT_DEVICEREMOVECOMPLETE)  ' 删除设备
        复制结构体 (val, lp, 14)
        .如果真 (val.dbcv_devicetype ＝ #DBT_DEVTYP_VOLUME)
            mask ＝ val.dbcv_unitmask
            .变量循环首 (0, 25, 1, i)
                .如果真 (位与 (mask, 1) ＝ 1)
                    跳出循环 ()
                .如果真结束
                mask ＝ 右移 (mask, 1)
            .变量循环尾 ()
            编辑框1.加入文本 (“USB磁盘被拔除，盘符:” ＋ 字符 (65 ＋ i) ＋ #换行符)
        .如果真结束

    .默认

    .判断结束

.默认

.判断结束
返回 (CallWindowProc (a, hwnd, msg, wp, lp))

.子程序 __启动窗口_将被销毁

a ＝ SetWindowLong (_启动窗口.取窗口句柄 (), -4, a)

.子程序 检测
.参数 盘符, 文本型
.局部变量 fn, 文本型

fn ＝ 寻找文件 (盘符 ＋ “:\*.*”, )
编辑框2.内容 ＝ “”
.判断循环首 (fn ≠ “”)
    编辑框2.加入文本 (fn ＋ #换行符)
    fn ＝ 寻找文件 (, )
.判断循环尾 ()