易语言断开进程网络连接源码

.版本 2
.支持库 iext
.支持库 eAPI

.程序集 窗口程序集1
.程序集变量 进程信息, 进程连接信息, , "0"
.程序集变量 状态数组, 文本型, , "0"

.子程序 _窗口1_创建完毕

状态数组 ＝ { “未知”, “已经关闭”, “监听”, “发送同步空闲字符”, “接收同步空闲字符”, “数据交换中”, “结束等待1”, “结束等待2”, “关闭等待”, “关闭中”, “命令正确应答”, “连接等待”, “删除TCP连接” }
取进程连接 ()

.子程序 取进程连接, , , 返回数目 借用网上大侠的源码
.局部变量 数据, 字节集
.局部变量 缓冲区大小, 整数型
.局部变量 数量, 整数型
.局部变量 位置1, 整数型
.局部变量 地址, 字节集
.局部变量 状态, 整数型
.局部变量 本地地址, 整数型
.局部变量 本地端口, 整数型
.局部变量 远程地址, 整数型
.局部变量 远程端口, 整数型
.局部变量 进程ID, 整数型
.局部变量 局部_进程信息, 进程连接信息
.局部变量 I, 整数型

超级列表框1.全部删除 ()
API_GetExtendedTcpTable (数据, 缓冲区大小, 假, 2, 5, 0)
数据 ＝ 取空白字节集 (缓冲区大小)
API_GetExtendedTcpTable (数据, 缓冲区大小, 假, 2, 5, 0)
数量 ＝ 取字节集数据 (取字节集左边 (数据, 4), 3, )
位置1 ＝ 4
清除数组 (进程信息)
.如果真 (数量 ＝ 0)
    返回 ()
.如果真结束
.计次循环首 (数量, I)
    状态 ＝ 取字节集数据 (取字节集中间 (数据, 位置1 ＋ 1, 4), 3, )
    地址 ＝ 取字节集中间 (数据, 位置1 ＋ 5, 4)
    本地端口 ＝ 取字节集数据 (取字节集中间 (数据, 位置1 ＋ 9, 4), 3, )
    远程端口 ＝ 取字节集数据 (取字节集中间 (数据, 位置1 ＋ 17, 4), 3, )
    进程ID ＝ 取字节集数据 (取字节集中间 (数据, 位置1 ＋ 21, 4), 3, )
    本地地址 ＝ 取字节集数据 (取字节集中间 (地址, 1, 4), #整数型, )
    地址 ＝ 取字节集中间 (数据, 位置1 ＋ 13, 4)
    远程地址 ＝ 取字节集数据 (取字节集中间 (地址, 1, 4), #整数型, )
    局部_进程信息.进程ID ＝ 进程ID
    局部_进程信息.进程连接.dwState ＝ 状态
    局部_进程信息.进程连接.dwLocalAddr ＝ 本地地址
    局部_进程信息.进程连接.dwLocalPort ＝ 本地端口
    局部_进程信息.进程连接.dwRemoteAddr ＝ 远程地址
    局部_进程信息.进程连接.dwRemotePort ＝ 远程端口
    超级列表框1.插入表项 (, , , , , )
    超级列表框1.置标题 (I － 1, 0, 到文本 (进程ID))
    超级列表框1.置标题 (I － 1, 1, 取进程名 (进程ID))
    超级列表框1.置标题 (I － 1, 2, GetAscIP (本地地址))
    超级列表框1.置标题 (I － 1, 3, 到文本 (API_ntohs (本地端口)))
    超级列表框1.置标题 (I － 1, 4, GetAscIP (远程地址))
    超级列表框1.置标题 (I － 1, 5, 到文本 (API_ntohs (远程端口)))
    超级列表框1.置标题 (I － 1, 6, 状态数组 [状态 ＋ 1])
    位置1 ＝ 位置1 ＋ 24
    加入成员 (进程信息, 局部_进程信息)
.计次循环尾 ()

.子程序 GetAscIP, 文本型
.参数 inn, 整数型
.局部变量 nStr, 整数型
.局部变量 lpStr, 整数型
.局部变量 retString, 文本型

retString ＝ 取空白文本 (32)
lpStr ＝ API_inet_ntoa (inn)
.如果 (lpStr ≠ 0)
    nStr ＝ API_lstrlen (lpStr)
    .如果真 (nStr ＞ 32)
        nStr ＝ 32
    .如果真结束
    API_CopyMemory (retString, lpStr, nStr)
    retString ＝ 取文本左边 (retString, nStr)
    返回 (retString)
.否则
    返回 (“无法获取IP”)
.如果结束


.子程序 取进程名, 文本型
.参数 进程ID, 整数型
.局部变量 系统进程, 进程信息, , "0"
.局部变量 计次变量, 整数型

系统进程 ＝ 取系统进程列表 ()
.计次循环首 (取数组成员数 (系统进程), 计次变量)
    .如果真 (系统进程 [计次变量].进程标识符 ＝ 进程ID)
        返回 (系统进程 [计次变量].进程名称)
        跳出循环 ()
    .如果真结束

.计次循环尾 ()
返回 (“”)

.子程序 _按钮1_被单击
.局部变量 I, 整数型

.计次循环首 (取数组成员数 (进程信息), I)
    .如果真 (到整数 (超级列表框1.取标题 (超级列表框1.现行选中项, 0)) ＝ 进程信息 [I].进程ID)
        进程信息 [I].进程连接.dwState ＝ #MIB_TCP_STATE_DELETE_TCB
        API_SetTcpEntry (进程信息 [I].进程连接)
    .如果真结束

.计次循环尾 ()
取进程连接 ()

.子程序 _按钮2_被单击

取进程连接 ()

@易语言入门教程