易语言鼠标连发源码

.版本 2

.程序集 窗口程序集_启动窗口
.程序集变量 hhkMouse, 整数型
.程序集变量 TimerID, 整数型

.子程序 __启动窗口_创建完毕

hhkMouse ＝ SetWindowsHookEx (#WH_MOUSE_LL, 到整数 (&LowLevelMouseProc), 0, 0)
检查 (hhkMouse ≠ 0)

.子程序 LowLevelMouseProc, 整数型
.参数 nCode, 整数型
.参数 wParam, 整数型
.参数 lParam, 整数型
.局部变量 POINT, POINT
.局部变量 hWnd, 整数型
.局部变量 Len, 整数型
.局部变量 Buffer, 文本型

.如果真 (nCode ＝ #HC_ACTION)
    .如果真 (wParam ＝ #WM_LBUTTONDOWN)
        GetCursorPos (POINT)
        hWnd ＝ GetAncestor (WindowFromPoint (POINT.x, POINT.y), #GA_ROOT)
        Len ＝ GetWindowTextLength (hWnd) ＋ 1
        Buffer ＝ 取空白文本 (Len)
        GetWindowText (hWnd, Buffer, Len)
        .如果真 (Buffer ＝ 编辑框_窗口.内容)
            TimerID ＝ SetTimer (0, 0, 到整数 (编辑框_速度.内容), 到整数 (&TimerProc))
        .如果真结束

    .如果真结束
    .如果真 (wParam ＝ #WM_LBUTTONUP)
        .如果真 (TimerID ≠ 0)
            TimerID ＝ 选择 (KillTimer (0, TimerID), 0, TimerID)
        .如果真结束

    .如果真结束

.如果真结束
返回 (CallNextHookEx (hhkMouse, nCode, wParam, lParam))

.子程序 TimerProc
.参数 hWnd, 整数型
.参数 uMsg, 整数型
.参数 idEvent, 整数型
.参数 dwTime, 整数型
.局部变量 POINT, POINT
.局部变量 _hWnd, 整数型
.局部变量 pos, 整数型

.如果真 (idEvent ＝ TimerID)
    ' mouse_event (#MOUSEEVENTF_LEFTDOWN, 0, 0, 0, 0)
    ' mouse_event (#MOUSEEVENTF_LEFTUP, 0, 0, 0, 0)
    ' ----------------------------------------------------------.
    GetCursorPos (POINT)
    _hWnd ＝ WindowFromPoint (POINT.x, POINT.y)
    ScreenToClient (_hWnd, POINT)
    pos ＝ 合并整数 (POINT.x, POINT.y)
    PostMessage (_hWnd, #WM_LBUTTONDOWN, #MK_LBUTTON, pos)
    PostMessage (_hWnd, #WM_LBUTTONUP, 0, pos)
.如果真结束


.子程序 __启动窗口_将被销毁

.如果真 (hhkMouse ≠ 0)
    UnhookWindowsHookEx (hhkMouse)
.如果真结束


.子程序 _按钮1_被单击

按钮1.标题 ＝ 到文本 (到整数 (按钮1.标题) ＋ 1)

@Lollipop