易语言自动更新 带进度下载源码（解析蓝奏网盘）

.版本 2
.支持库 internet

.程序集 窗口程序集_启动窗口
.程序集变量 真实下载地址, 文本型
.程序集变量 文件长度, 整数型
.程序集变量 文件名, 文本型

.子程序 __启动窗口_创建完毕

.如果真 (是否为调试版 () ＝ 假)
    安装回调 ()  ' 安装进度显示功能，    只能编译使用， 调试运行无法使用。
.如果真结束


.子程序 _按钮1_被单击
.局部变量 下载的数据, 字节集

按钮1.标题 ＝ “解析lanzou地址中...”
处理事件 ()
.如果 (解析lanzou地址 (编辑框1.内容, 真实下载地址, 文件长度, 文件名))
    按钮1.标题 ＝ “下载文件中...”
    处理事件 ()
    进度条1.位置 ＝ 0
    下载的数据 ＝ HTTP读文件 (真实下载地址)
    进度条1.位置 ＝ 100
    标签3.标题 ＝ “100%”
    写到文件 (取运行目录 () ＋ “” ＋ 文件名, 下载的数据)
    信息框 (“文件名：” ＋ 文件名 ＋ #换行符 ＋ “文件长度：” ＋ 到文本 (文件长度) ＋ #换行符 ＋ “恭喜！下载完成！ 已经写入文件到当前目录。 ”, 0, , )
.否则
    信息框 (“解析lanzou地址失败”, 0, , )
.如果结束
按钮1.标题 ＝ “开始下载”

.子程序 解析lanzou地址, 逻辑型
.参数 文件网盘地址, 文本型, , 例如：  http://pan.lanzou.com/551083
.参数 保存下载地址的变量, 文本型, 参考
.参数 保存文件尺寸的变量, 整数型, 参考
.参数 保存文件名的变量, 文本型, 参考
.局部变量 内容, 文本型
.局部变量 url, 文本型
.局部变量 文件名字, 文本型
.局部变量 文件大小, 整数型

内容 ＝ URL解码_UTF8 (到文本 (HTTP读文件 (文件网盘地址)))
url ＝ 取文本中间_E (内容, #url, #url_end)
保存下载地址的变量 ＝ url ＋ 取文本中间_E (内容, #后缀, #后缀_end)
保存文件名的变量 ＝ 取文本中间_E (内容, “文件名字：</span>”, “<br>”)
保存文件尺寸的变量 ＝ 到整数 (到小数 (取文本中间_E (内容, “文件大小：</span>”, “ K<br>”)) × 1024)
.如果真 (保存文件尺寸的变量 ＝ 0)
    保存文件尺寸的变量 ＝ 到整数 (到小数 (取文本中间_E (内容, “文件大小：</span>”, “ M<br>”)) × 1024 × 1024)
.如果真结束
返回 (保存下载地址的变量 ≠ “” 且 保存文件尺寸的变量 ＞ 0)

.子程序 进度回调
.参数 ecx, 整数型
.局部变量 当前已下载长度, 整数型
.局部变量 百分比, 整数型
.局部变量 数据, 字节集

数据 ＝ 取空白字节集 (4)
ReadProcessMemory (-1, ecx ＋ 16, 数据, 4, 0)
当前已下载长度 ＝ 取字节集数据 (数据, #整数型, )
百分比 ＝ 到整数 (当前已下载长度 ÷ 文件长度 × 100)
进度条1.位置 ＝ 百分比
标签3.标题 ＝ 到文本 (百分比) ＋ “%”
处理事件 ()

@猫吃了易语言