Cloudreve 云盘直链获取源码

Cloudreve 云盘直链获取源码

@虐ふ1999

.版本 2
.支持库 spec

.程序集 程序集1

.子程序 _启动子程序, 整数型, , 本子程序在程序启动后最先执行

调试输出 (获取Could (“http://127.0.0.1:82/#/s/PvcB”))
返回 (0)  ' 可以根据您的需要返回任意数值

.子程序 获取Could, 文本型, 公开
.参数 直链, 文本型
.局部变量 json, zyJsonDocument
.局部变量 cok, 文本型
.局部变量 tmp, 文本型, , "0"
.局部变量 tmp1, 文本型

tmp ＝ 分割文本 (直链, “/”, )
json.解析 (到文本 (网页_访问_x (tmp [1] ＋ “//” ＋ tmp [3] ＋ “/api/v3/share/download/” ＋ tmp [取数组成员数 (tmp)], 2, , , cok, #协议头, , , , , )), #JV解析_USC2解码, , )
返回 (json.取文本 (“data”))

.子程序 网页_访问_x, 字节集, 公开, ServerXMLHTTP
.参数 网址, 文本型, , 完整的网页地址,必须包含http://或者https://
.参数 访问方式, 整数型, 可空, 0=GET 1=POST  2=PUT  3=OPTIONS  4=DELETE  5=PATCH
.参数 提交信息, 文本型, 可空, POST专用
.参数 提交Cookies, 文本型, 可空, 本参数传递变量时会自动回传返回的Cookie
.参数 返回Cookies, 文本型, 参考 可空, 返回的Cookie
.参数 附加协yi头, 文本型, 可空, 一行一个请用换行符隔开,建议填写常量值或文本值,防止因传参引发错误
.参数 返回协yi头, 文本型, 参考 可空, 返回的协yi头
.参数 禁止重定向, 逻辑型, 可空, 默认不禁止网页重定向
.参数 字节集提交, 字节集, 可空
.参数 代理IP, 文本型, 可空, 8.8.8.8:8080   8.8.8.8:8080|user|pwd
.参数 超时, 整数型, 可空
.局部变量 Xmlhttp, 对象
.局部变量 heard, 文本型, , "0"
.局部变量 Pxyi, 文本型, , "0"
.局部变量 Pxyu, 文本型, , , 代理帐号
.局部变量 Pxyp, 文本型, , , 代理密码
.局部变量 I
.局部变量 X
.局部变量 RevCode, 字节集
.局部变量 变体字节集, 变体型

' CoInitialize (0)
.如果真 (Xmlhttp.创建 (“MSXML2.ServerXMLHTTP.6.0”, ) ＝ 假)
    返回 ({  })
.如果真结束
Xmlhttp.方法 (“setOption”, 2, 13056)  ' 忽略所有ssl错误
Xmlhttp.方法 (“setOption”, 3, “VeriSign Class 3 Public Primary CA”)  ' 设置 CA 证书
Xmlhttp.方法 (“SetTimeouts”, 超时, 超时, 超时, 超时)  ' 设置超时
.如果真 (寻找文本 (代理IP, “:”, , 假) ＞ 0)
    .如果真 (寻找文本 (代理IP, “|”, , 假) ＞ 0)
        Pxyi ＝ 分割文本 (代理IP, “|”, )
        Pxyu ＝ Pxyi [2]
        Pxyp ＝ Pxyi [3]
        代理IP ＝ Pxyi [1]
    .如果真结束
    Xmlhttp.方法 (“SetProxy”, 2, 代理IP)
.如果真结束
.如果真 (访问方式 ＝ 0)
    Xmlhttp.方法 (“Open”, “GET”, 网址, 假, Pxyu, Pxyp)  ' , 代理帐号, 代理密码
.如果真结束
.如果真 (访问方式 ＝ 1)
    Xmlhttp.方法 (“Open”, “POST”, 网址, 假, Pxyu, Pxyp)
.如果真结束
.如果真 (访问方式 ＝ 2)
    Xmlhttp.方法 (“Open”, “PUT”, 网址, 假, Pxyu, Pxyp)
.如果真结束
.如果真 (访问方式 ＝ 3)
    Xmlhttp.方法 (“Open”, “OPTIONS”, 网址, 假, Pxyu, Pxyp)
.如果真结束
.如果真 (访问方式 ＝ 4)
    Xmlhttp.方法 (“Open”, “DELETE”, 网址, 假, Pxyu, Pxyp)
.如果真结束
.如果真 (访问方式 ＝ 5)
    Xmlhttp.方法 (“Open”, “PATCH”, 网址, 假, Pxyu, Pxyp)
.如果真结束

.如果真 (禁止重定向)
    Xmlhttp.写属性 (“Option”, 6, 0)
.如果真结束
.如果真 (寻找文本 (附加协yi头, “: ”, , 假) ＞ 0)
    Pxyi ＝ 分割文本 (附加协yi头, #换行符, )
    .计次循环首 (取数组成员数 (Pxyi), I)
        .如果真 (寻找文本 (Pxyi [I], “: ”, , 假) ＞ 0)
            heard ＝ 分割文本 (Pxyi [I], “: ”, )
            Xmlhttp.方法 (“SetRequestHeader”, heard [1], heard [2])
        .如果真结束

    .计次循环尾 ()
.如果真结束
.如果真 (Pxyu ≠ “”)
    Xmlhttp.方法 (“SetRequestHeader”, “Proxy-Authorization”, “Basic ” ＋ 编码_BASE64编码 (到字节集 (Pxyu ＋ “:” ＋ Pxyp)))
.如果真结束

.如果真 (提交Cookies ≠ “”)
    Xmlhttp.方法 (“SetRequestHeader”, “Cookie”, 提交Cookies)
.如果真结束
.判断开始 (字节集提交 ＝ {  })
    Xmlhttp.方法 (“Send”, 提交信息)
.默认
    变体字节集.赋值 (字节集提交, )
    Xmlhttp.方法 (“Send”, 变体字节集)
.判断结束
RevCode ＝ Xmlhttp.读属性 (“ResponseBody”, ).取字节集 ()
返回协yi头 ＝ Xmlhttp.读文本属性 (“GetallResponseHeaders”, )
heard ＝ 分割文本 (返回协yi头, #换行符, )
返回Cookies ＝ “”
.计次循环首 (取数组成员数 (heard), I)
    .如果真 (寻找文本 (heard [I], “Set-Cookie”, , 假) ≠ -1)
        .判断开始 (寻找文本 (heard [I], “;”, , 假) ≠ -1)
            返回Cookies ＝ 返回Cookies ＋ 删首尾空 (jkGs1 (heard [I], “Set-Cookie:”, “;”)) ＋ “; ”
        .默认
            返回Cookies ＝ 返回Cookies ＋ 删首尾空 (子文本替换 (heard [I], “Set-Cookie:”, , , , 假)) ＋ “; ”
        .判断结束

    .如果真结束

.计次循环尾 ()
返回Cookies ＝ 取文本左边 (返回Cookies, 取文本长度 (返回Cookies) － 2)
Xmlhttp.清除 ()
' CoUninitialize ()
返回 (RevCode)


.子程序 jkGs1, 文本型, , 代码来自 精易模块
.参数 欲取全文本, 文本型, , 比如：欲取全文本为 12345
.参数 前面文本, 文本型, , 3的前面为“2”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 后面文本, 文本型, , 3的后面为“4”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 起始搜寻位置, 整数型, 可空, 可空,这里是指搜寻 参数二 前面文本 的开始位置
.参数 是否不区分大小写, 逻辑型, 可空, 为真不区分大小写，为假区分。
.局部变量 局_前面文本位置, 整数型
.局部变量 局_后面文本位置, 整数型
.局部变量 局_前面文本, 文本型
.局部变量 局_后面文本, 文本型

局_前面文本 ＝ 子文本替换 (前面文本, “#引号”, #引号, , , 真)
局_后面文本 ＝ 子文本替换 (后面文本, “#引号”, #引号, , , 真)
局_前面文本位置 ＝ 寻找文本 (欲取全文本, 局_前面文本, 起始搜寻位置, 是否不区分大小写)
.如果真 (局_前面文本位置 ≠ -1)
    局_前面文本位置 ＝ 局_前面文本位置 ＋ 取文本长度 (局_前面文本)
.如果真结束
局_后面文本位置 ＝ 寻找文本 (欲取全文本, 局_后面文本, 局_前面文本位置, 是否不区分大小写)
.如果真 (局_前面文本位置 ＝ -1 或 局_后面文本位置 ＝ -1)
    返回 (“”)
.如果真结束
返回 (取文本中间 (欲取全文本, 局_前面文本位置, 局_后面文本位置 － 局_前面文本位置))