易语言EDB数据库使用源码

易语言EDB数据库使用源码演示了如何创建EDB数据库，增加，删除，查询，修改数据库操作。

@易语言在线学习

.版本 2
.支持库 iext

.程序集 窗口程序集1

.子程序 _按钮创建_被单击
.局部变量 字段, 字段信息, , "4"

.如果 (按钮创建.标题 ＝ “创建数据库”)
    .如果真 (取反 (文件是否存在 (取运行目录 () ＋ “创建数据库.edb”)))
        字段 [1].名称 ＝ “姓名”
        字段 [1].类型 ＝ #文本型
        字段 [1].最大文本长度 ＝ 10
        字段 [2].名称 ＝ “语文”
        字段 [3].名称 ＝ “数学”
        字段 [4].名称 ＝ “总分”
        连续赋值 (#整数型, 字段 [2].类型, 字段 [3].类型, 字段 [4].类型)
        创建 (取运行目录 () ＋ “创建数据库.edb”, 字段)
    .如果真结束
    按钮创建.标题 ＝ “自动排序”
    打开 (取运行目录 () ＋ “创建数据库.edb”, , , , , , )
    刷新记录 (假)
    外形框1.可视 ＝ 真
.否则
    信息框 (超级列表框排序 (超级列表框1, 3, 假, , 3), 0, )
.如果结束


.子程序 _编辑框1_字符输入, 整数型
.参数 字符代码, 整数型

.如果真 (字符代码 ＜ 127 且 字符代码 ≠ #退格键)
    返回 (0)
.如果真结束


.子程序 _编辑框2_字符输入, 整数型
.参数 字符代码, 整数型

.如果真 (字符代码 ＝ #减号键)
    返回 (0)
.如果真结束


.子程序 _编辑框3_字符输入, 整数型
.参数 字符代码, 整数型

.如果真 (字符代码 ＝ #减号键)
    返回 (0)
.如果真结束


.子程序 __启动窗口_可否被关闭, 逻辑型

关闭 ()

.子程序 _添加_被单击

.如果真 (取文本长度 (编辑框1.内容) × 取文本长度 (编辑框2.内容) × 取文本长度 (编辑框3.内容) ＝ 0)
    信息框 (“请输入完整的资料”, 0, )
    返回 ()
.如果真结束
组合框1.现行选中项 ＝ 0
_组合框1_列表项被选择 ()
加记录 (编辑框1.内容, 到数值 (编辑框2.内容), 到数值 (编辑框3.内容), 到数值 (编辑框2.内容) ＋ 到数值 (编辑框3.内容))
刷新记录 (假)

.子程序 刷新记录
.参数 是否查询, 逻辑型
.局部变量 NN, 整数型

连续赋值 (“”, 编辑框1.内容, 编辑框2.内容, 编辑框3.内容)
超级列表框1.全部删除 ()
到首记录 ()
.如果 (是否查询 ＝ 假)
    .计次循环首 (取记录数 (), NN)
        超级列表框1.插入表项 (NN － 1, , , , , 取记录号 ())
        超级列表框1.置标题 (NN － 1, 0, 读 (1))
        超级列表框1.置标题 (NN － 1, 1, 到文本 (读 (2)))
        超级列表框1.置标题 (NN － 1, 2, 到文本 (读 (3)))
        超级列表框1.置标题 (NN － 1, 3, 到文本 (读 (4)))
        跳过 ()
    .计次循环尾 ()
.否则
    NN ＝ -1
    .判断循环首 (查询条件 ())
        NN ＝ NN ＋ 1
        超级列表框1.插入表项 (NN, , , , , 取记录号 ())
        超级列表框1.置标题 (NN, 0, 读 (1))
        超级列表框1.置标题 (NN, 1, 到文本 (读 (2)))
        超级列表框1.置标题 (NN, 2, 到文本 (读 (3)))
        超级列表框1.置标题 (NN, 3, 到文本 (读 (4)))
        跳过 ()
    .判断循环尾 ()
.如果结束


.子程序 _刷新_被单击

刷新记录 (组合框1.现行选中项 ≠ 0 且 编辑框4.内容 ≠ “”)

.子程序 __启动窗口_创建完毕

外形框1.可视 ＝ 假

.子程序 _修改_被单击

.如果真 (超级列表框1.现行选中项 ＝ -1)
    信息框 (“未选择记录，不能修改”, 0, )
    返回 ()
.如果真结束
.如果真 (取文本长度 (编辑框1.内容) × 取文本长度 (编辑框2.内容) × 取文本长度 (编辑框3.内容) ＝ 0)
    信息框 (“请输入完整的资料”, 0, )
    返回 ()
.如果真结束
修改 (编辑框1.内容, 到数值 (编辑框2.内容), 到数值 (编辑框3.内容), 到数值 (编辑框2.内容) ＋ 到数值 (编辑框3.内容))
_刷新_被单击 ()

.子程序 _删除_被单击

.如果真 (超级列表框1.现行选中项 ＝ -1)
    信息框 (“未选择记录，不能删除”, 0, )
    返回 ()
.如果真结束
.如果真 (信息框 (“真的删除吗？”, 33, “请确认”) ＝ #确认钮)
    删除 ()
    彻底删除 ()
.如果真结束
_刷新_被单击 ()

.子程序 _超级列表框1_当前表项被改变

跳到 (超级列表框1.取表项数值 (超级列表框1.现行选中项))
编辑框1.内容 ＝ 读 (1)
编辑框2.内容 ＝ 到文本 (读 (2))
编辑框3.内容 ＝ 到文本 (读 (3))

.子程序 _按钮查询_被单击

.如果 (组合框1.现行选中项 ＝ 0)
    信息框 (“请选择要查询的项目”, 0, )
.否则
    刷新记录 (真)
.如果结束


.子程序 查询条件, 逻辑型

.如果 (组合框1.现行选中项 ＝ 1)
    返回 (查找 (读 (1) ＝ 编辑框4.内容))
.否则
    返回 (查找 (读 (组合框1.现行选中项) ＝ 到数值 (编辑框4.内容)))
.如果结束


.子程序 _组合框1_列表项被选择

.如果 (组合框1.现行选中项 ＝ 0)
    编辑框4.禁止 ＝ 真
.否则
    编辑框4.禁止 ＝ 假
    .如果 (组合框1.现行选中项 ≥ 1 且 组合框1.现行选中项 ≤ 3)
        事件转移 (编辑框4, 多项选择 (组合框1.现行选中项, 编辑框1, 编辑框2, 编辑框2))
    .否则
        编辑框4.输入方式 ＝ 3
        编辑框4.最大允许长度 ＝ 3
    .如果结束

.如果结束