易语言书法学习系统源码

书法学习系统

.版本 2

.子程序 文本分行, 文本型, , 把一段长文本按你指定的字数分行
.参数 要处理的文本, 文本型
.参数 是否全角, 逻辑型, 可空, 是否将半角转换为全角,如果为空即不转换
.参数 每行字数, 整数型, 可空, 半角字数，如果为空，将不进行分行操作，直接返回文本内容。
.参数 首空字节数, 整数型, 可空, 在每行前面加入空格,如果为空,为0,即不加空格
.参数 是否强行分行, 逻辑型, 可空, 为真则强行按设定长度分行。为假则保留连续半角数字或字母为一行。默认为假。
.局部变量 结果文本, 文本型
.局部变量 开始位置, 整数型
.局部变量 读取长度, 整数型
.局部变量 半角位置, 整数型
.局部变量 容器1, 整数型

.如果真 (是否为空 (每行字数))
    返回 (要处理的文本)
.如果真结束
.如果真 (是否为空 (是否强行分行))
    是否强行分行 ＝ 假
.如果真结束

.如果真 (是否全角 ＝ 真)
    要处理的文本 ＝ 子文本替换 (要处理的文本, “...”, “…”, 1, , 真)
    要处理的文本 ＝ 子文本替换 (要处理的文本, “->”, “→”, 1, , 真)
    要处理的文本 ＝ 子文本替换 (要处理的文本, “<-”, “←”, 1, , 真)
    要处理的文本 ＝ 子文本替换 (要处理的文本, “--”, “—”, 1, , 真)
    要处理的文本 ＝ 到全角 (要处理的文本)
.如果真结束

.如果真 (首空字节数 ≥ 1)
    要处理的文本 ＝ 取空白文本 (首空字节数) ＋ 要处理的文本
    要处理的文本 ＝ 子文本替换 (要处理的文本, #换行符, #换行符 ＋ 取空白文本 (首空字节数), 1, , 真)
.如果真结束

结果文本 ＝ 要处理的文本
开始位置 ＝ 1
.判断循环首 (取文本长度 (结果文本) － 开始位置 ＞ 每行字数)
    .判断循环首 (读取长度 ＜ 每行字数)
        .如果 (取代码 (结果文本, 开始位置 ＋ 读取长度) ≥ 127)
            读取长度 ＝ 读取长度 ＋ 2
        .否则
            .如果 (取文本中间 (结果文本, 开始位置 ＋ 读取长度, 1) ＝ “ ”)
                读取长度 ＝ 读取长度 ＋ 1
            .否则
                .如果 (取文本中间 (结果文本, 开始位置 ＋ 读取长度, 2) ≠ #换行符)
                    半角位置 ＝ 读取长度
                    读取长度 ＝ 读取长度 ＋ 1
                    .判断循环首 (取代码 (结果文本, 开始位置 ＋ 读取长度) ＜ 127 且 取文本中间 (结果文本, 开始位置 ＋ 读取长度, 1) ≠ “ ”)
                        .如果 (取文本中间 (结果文本, 开始位置 ＋ 读取长度, 2) ≠ #换行符)
                            .如果 (读取长度 ≥ 每行字数)
                                跳出循环 ()
                            .否则
                                读取长度 ＝ 读取长度 ＋ 1
                            .如果结束

                        .否则
                            开始位置 ＝ 开始位置 ＋ 读取长度 ＋ 2
                            读取长度 ＝ 0
                            跳出循环 ()
                        .如果结束

                    .判断循环尾 ()
                    .判断开始 (读取长度 ≥ 每行字数)
                        .如果 (是否强行分行 ＝ 假)
                            读取长度 ＝ 选择 (半角位置 ＝ 0, 每行字数, 半角位置)
                        .否则
                            读取长度 ＝ 每行字数
                        .如果结束
                        跳出循环 ()
                    .判断 (读取长度 ＜ 每行字数 且 取文本中间 (结果文本, 开始位置 ＋ 读取长度, 1) ＝ “ ”)
                        读取长度 ＝ 读取长度 ＋ 1
                    .默认

                    .判断结束

                .否则
                    开始位置 ＝ 开始位置 ＋ 读取长度 ＋ 2
                    读取长度 ＝ 0
                .如果结束

            .如果结束

        .如果结束
        .如果真 (读取长度 ＝ 每行字数 － 1 且 取代码 (结果文本, 开始位置 ＋ 读取长度) ≥ 127)
            跳出循环 ()
        .如果真结束

    .判断循环尾 ()
    结果文本 ＝ 取文本左边 (结果文本, 开始位置 ＋ 读取长度 － 1) ＋ #换行符 ＋ 取文本右边 (结果文本, 取文本长度 (结果文本) － 读取长度 － 开始位置 ＋ 1)
    开始位置 ＝ 开始位置 ＋ 读取长度 ＋ 2
    读取长度 ＝ 0
.判断循环尾 ()
返回 (结果文本)

@易语言教程网