易语言全屏找图脚本源码 速度超快

.版本 2

.子程序 超速精确找图, 坐标型, 公开, 找不到返回-1,-1 范围越小，相似度越大，容差为0时，速度越快
.参数 左上横坐标, 整数型, 可空, 默认为0，左上横坐标
.参数 左上纵坐标, 整数型, 可空, 默认为0，左上纵坐标
.参数 右下横坐标, 整数型, 可空, 默认为屏幕宽度，右下横坐标
.参数 右下纵坐标, 整数型, 可空, 默认为屏幕高度，右下纵坐标
.参数 找的图片, 字节集, , 要找的图片
.局部变量 桌面句柄, 整数型
.局部变量 源场景, 整数型
.局部变量 位图句柄, 整数型
.局部变量 位图像素点阵, 字节集
.局部变量 位图信息, 位图信息型
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 找到返回, 整数型
.局部变量 屏幕宽度, 整数型
.局部变量 屏幕高度, 整数型
.局部变量 计数器, 整数型
.局部变量 位图高, 整数型
.局部变量 位图宽, 整数型
.局部变量 余数, 整数型
.局部变量 拆分字节集, 字节集, , "0"
.局部变量 取图, 整数型
.局部变量 坐标, 坐标型
.局部变量 k, 整数型
.局部变量 临时图片, 字节集
.局部变量 n, 整数型
.局部变量 图片像素点阵, 字节集
.局部变量 图片信息, 位图信息型

位图高 ＝ 找的图片 [23] ＋ 找的图片 [24] × 256
位图宽 ＝ 找的图片 [19] ＋ 找的图片 [20] × 256
屏幕宽度 ＝ 右下横坐标 － 左上横坐标
屏幕高度 ＝ 右下纵坐标 － 左上纵坐标
.如果真 (位图宽 × 3 ％ 4 ＝ 0)
    余数 ＝ 0
.如果真结束
.如果真 (位图宽 × 3 ％ 4 ≠ 0)
    余数 ＝ 4 － 位图宽 × 3 ％ 4
.如果真结束
重定义数组 (拆分字节集, 假, 位图高)
计数器 ＝ 1
临时图片 ＝ 取字节集右边 (找的图片, 取字节集长度 (找的图片) － 54)
.判断循环首 (计数器 ≤ 位图高)
    拆分字节集 [计数器] ＝ 取字节集中间 (临时图片, 1 ＋ (计数器 － 1) × (位图宽 × 3 ＋ 余数), 位图宽 × 3)
    计数器 ＝ 计数器 ＋ 1
.判断循环尾 ()
桌面句柄 ＝ 取设备场景_ (0)
源场景 ＝ 创建内存场景_ (桌面句柄)
位图句柄 ＝ 创建设备场景位图_ (桌面句柄, 右下横坐标, 右下纵坐标)
选入设备场景_ (源场景, 位图句柄)
图片信息.位深度 ＝ 24
图片信息.位图位面数 ＝ 1
图片信息.位图宽度 ＝ 位图宽
图片信息.位图高度 ＝ 位图高
.如果真 (图片信息.位图宽度 × 3 ％ 4 ＝ 0)
    图片信息.位图大小 ＝ 图片信息.位图宽度 × 3 × 图片信息.位图高度
.如果真结束
.如果真 (图片信息.位图宽度 × 3 ％ 4 ≠ 0)
    图片信息.位图大小 ＝ 图片信息.位图宽度 × 3 × 图片信息.位图高度 ＋ 图片信息.位图高度 × (4 － 图片信息.位图宽度 × 3 ％ 4)
.如果真结束
图片信息.结果大小 ＝ 40
图片信息.压缩率 ＝ 0
位图信息.位深度 ＝ 24
位图信息.位图位面数 ＝ 1
位图信息.位图宽度 ＝ 屏幕宽度
位图信息.位图高度 ＝ 屏幕高度
.如果真 (位图信息.位图宽度 × 3 ％ 4 ＝ 0)
    位图信息.位图大小 ＝ 位图信息.位图宽度 × 3 × 位图信息.位图高度
    取图 ＝ 0
    k ＝ 1
.如果真结束
.如果真 (位图信息.位图宽度 × 3 ％ 4 ≠ 0)
    位图信息.位图大小 ＝ 位图信息.位图宽度 × 3 × 位图信息.位图高度 ＋ 位图信息.位图高度 × (4 － 位图信息.位图宽度 × 3 ％ 4)
    取图 ＝ 4 － 位图信息.位图宽度 × 3 ％ 4
    k ＝ 0
.如果真结束
位图信息.结果大小 ＝ 40
位图信息.压缩率 ＝ 0
复制场景位图_ (源场景, 0, 0, 屏幕宽度, 屏幕高度, 桌面句柄, 左上横坐标, 左上纵坐标, 13369376)
位图像素点阵 ＝ 取空白字节集 (位图信息.位图大小)
图片像素点阵 ＝ 取空白字节集 (图片信息.位图大小)
取位图二进制位_ (源场景, 位图句柄, 0, 位图信息.位图高度, 位图像素点阵, 位图信息, #DIB_RGB_COLORS)
计数器 ＝ 1
n ＝ 1
找到返回 ＝ 寻找字节集 (位图像素点阵, 拆分字节集 [计数器], 1)
.判断循环首 (找到返回 ＞ 0)
    y ＝ 右下纵坐标 － 取整 (找到返回 ÷ (屏幕宽度 × 3 ＋ 取图)) － 1
    x ＝ 右下横坐标 － 取整 (((右下纵坐标 － y) × (屏幕宽度 × 3 ＋ 取图) － 找到返回) ÷ 3) － k
    ' x ＝ 屏幕宽度 － 取整 (((右下纵坐标 － y) × 屏幕宽度 × 3 ＋ (右下纵坐标 － y) × 取图 － 找到返回) ÷ 3) － k ＋ 左上横坐标
    ' 是否找到 ＝ 精确找图子程序 (x, y － 位图高 ＋ 1 ＋ 计数器 － 1, x ＋ 位图宽, y ＋ 1 ＋ 计数器 － 1, 找的图片)
    ' 复制场景位图_ (源场景, 0, 0, 位图宽, 位图高, 桌面句柄, 右下横坐标 － 取整 (((取整 (找到返回 ÷ 屏幕宽度 ÷ 3) ＋ 1) × (屏幕宽度 × 3 ＋ 取图) － 找到返回) ÷ 3) － k, 右下纵坐标 － 取整 (找到返回 ÷ 屏幕宽度 ÷ 3) － k － 位图高 ＋ 计数器, 13369376)
    ' 输出调试文本 (((右下纵坐标 － y) × 屏幕宽度 × 3 ＋ (右下纵坐标 － y) × 取图 － 找到返回) ÷ 3)
    复制场景位图_ (源场景, 0, 0, 位图宽, 位图高, 桌面句柄, x, y － 位图高 ＋ 计数器, 13369376)
    取位图二进制位_ (源场景, 位图句柄, 0, 图片信息.位图高度, 图片像素点阵, 图片信息, #DIB_RGB_COLORS)
    .如果真 (临时图片 ＝ 图片像素点阵)
        坐标.横坐标 ＝ x
        坐标.纵坐标 ＝ y － 位图高 ＋ 计数器
        删除对象_ (位图句柄)
        删除设备场景_ (源场景)
        释放设备场景_ (0, 桌面句柄)
        返回 (坐标)
    .如果真结束
    .如果真 (n ＞ 30)
        计数器 ＝ 计数器 ＋ 1
        n ＝ 0
        .如果真 (计数器 ＞ 位图高)
            删除对象_ (位图句柄)
            删除设备场景_ (源场景)
            释放设备场景_ (0, 桌面句柄)
            坐标.横坐标 ＝ -1
            坐标.纵坐标 ＝ -1
            返回 (坐标)
        .如果真结束

    .如果真结束
    找到返回 ＝ 寻找字节集 (位图像素点阵, 拆分字节集 [计数器], 找到返回 ＋ 1)
    n ＝ n ＋ 1
.判断循环尾 ()
删除对象_ (位图句柄)
删除设备场景_ (源场景)
释放设备场景_ (0, 桌面句柄)
坐标.横坐标 ＝ -1
坐标.纵坐标 ＝ -1
返回 (坐标)

@小黑s