易语言图片句柄取图片字节集

易语言图片句柄取图片字节集

@urenai

.版本 2

.程序集 程序集1

.子程序 _启动子程序, 整数型, , 请在本子程序中放置动态链接库初始化代码



返回 (0)  ' 返回值被忽略。

.子程序 字节集_取空白, 字节集
.参数 len, 整数型
.局部变量 address, 整数型
.局部变量 ret, 字节集

.如果真 (len ＜ 1)
    返回 ({  })
.如果真结束
address ＝ _GlobalAlloc (64, len)
.如果真 (address ＝ 0)
    返回 ({  })
.如果真结束
ret ＝ 指针到字节集 (address, len)
_GlobalFree (address)
返回 (ret)

.子程序 字节集_到整数, 整数型
.参数 字节集, 字节集
.局部变量 ret, 整数型
.局部变量 address, 整数型
.局部变量 len, 整数型

address ＝ _lstrcpyn_字节集 (字节集, 字节集, 0)
len ＝ 取字节集长度 (字节集)
.如果 (len ＜ 4)
    _RtlMoveMemory_整数型 (ret, address, len)
.否则
    _RtlMoveMemory_整数型 (ret, address, 4)
.如果结束
返回 (ret)

.子程序 图片句柄取图片, 字节集, , 返回的图片格式为位图。
.参数 hBitmap, 整数型
.局部变量 Bitmap, BITMAP
.局部变量 Resource, 字节集
.局部变量 BitmapFileHeader, BITMAPFILEHEADER
.局部变量 bfh, 字节集
.局部变量 hMemDC, 整数型
.局部变量 BitmapInfo, BITMAPINFO
.局部变量 bi, 字节集

_GetObjectA (hBitmap, 24, Bitmap)
hMemDC ＝ _CreateCompatibleDC (0)
BitmapInfo.BITMAPINFOHEADER.biSize ＝ 44
_GetDIBits_整数型 (hMemDC, hBitmap, 0, 0, 0, BitmapInfo, 0)
Resource ＝ 字节集_取空白 (BitmapInfo.BITMAPINFOHEADER.biSizeImage)
BitmapInfo.BITMAPINFOHEADER.biCompression ＝ 0
_GetDIBits_字节集 (hMemDC, hBitmap, 0, Bitmap.bmHeight, Resource, BitmapInfo, 0)
bi ＝ 字节集_取空白 (BitmapInfo.BITMAPINFOHEADER.biSize)
_RtlMoveMemory_BITMAPINFO (bi, BitmapInfo, BitmapInfo.BITMAPINFOHEADER.biSize)
BitmapFileHeader.bfType ＝ 19778
BitmapFileHeader.bfOffBits ＝ 14 ＋ BitmapInfo.BITMAPINFOHEADER.biSize
BitmapFileHeader.bfSize ＝ BitmapFileHeader.bfOffBits ＋ BitmapInfo.BITMAPINFOHEADER.biSizeImage
连续赋值 (0, BitmapFileHeader.bfReserved1, BitmapFileHeader.bfReserved2)
bfh ＝ 字节集_取空白 (14)
_RtlMoveMemory_BITMAPFILEHEADER (bfh, BitmapFileHeader, 14)
_DeleteDC (hMemDC)
返回 (bfh ＋ bi ＋ Resource)