易语言过滤HTML,JS,CSS,空格,换行符源码

.版本 2

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击

编辑框2.内容 ＝ 过滤代码 (编辑框1.内容, 选择框1.选中, 选择框2.选中, 选择框3.选中, 选择框4.选中, 选择框5.选中)

.子程序 过滤代码, 文本型, 公开, By:Woxl QQ377343266
.参数 原始内容, 文本型
.参数 过滤HTML, 逻辑型, 可空
.参数 过滤JS, 逻辑型, 可空
.参数 过滤CSS, 逻辑型, 可空
.参数 过滤空格, 逻辑型, 可空, 含制表符
.参数 过滤换行符, 逻辑型, 可空
.参数 是否线程中使用, 逻辑型, 可空
.局部变量 对象, 对象
.局部变量 Ret, 文本型

.如果真 (是否线程中使用)
    CoInitialize (0)
.如果真结束
对象.创建 (“VBScript.RegExp”, )
对象.写属性 (“Global”, 1)
对象.写属性 (“Multiline”, 1)
Ret ＝ 原始内容
.如果真 (过滤CSS)
    对象.写属性 (“Pattern”, “<\s*style[^>]*>(.|[\r\n])*?<\s*\/style[^>]*>”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
.如果真结束
.如果真 (过滤JS)
    对象.写属性 (“Pattern”, “<\s*script[^>]*>(.|[\r\n])*?<\s*\/script[^>]*>”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
.如果真结束
.如果真 (过滤HTML)
    对象.写属性 (“Pattern”, “<\/?[^>]+>”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
    对象.写属性 (“Pattern”, “&[a-z]+;”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
.如果真结束
.如果真 (过滤空格)
    对象.写属性 (“Pattern”, “((?![\r\n])\s)+”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
.如果真结束
.如果真 (过滤换行符)
    对象.写属性 (“Pattern”, “
”)
    Ret ＝ 对象.文本方法 (“Replace”, Ret, “”)
.如果真结束
对象.清除 ()
.如果真 (是否线程中使用)
    CoUninitialize ()
.如果真结束
返回 (Ret)

@woxl