易语言高级表格限制录入格式－十六进制

.版本 2

.程序集 窗口程序集_启动窗口
.程序集变量 集_HOOK, HOOK类
.程序集变量 原窗口函数地址

.子程序 __启动窗口_创建完毕

集_HOOK.安装 (“USER32.DLL”, “CreateWindowExA”, &创建控件)

.子程序 __启动窗口_将被销毁

集_HOOK.卸载 ()

.子程序 创建控件, 整数型
.参数 dwExStyle, 整数型
.参数 lpClassName, 文本型
.参数 lpWindowName, 文本型
.参数 dwStyle, 整数型
.参数 x, 整数型
.参数 y, 整数型
.参数 nWidth, 整数型
.参数 nHeight, 整数型
.参数 hWndParent, 整数型
.参数 hMenu, 整数型
.参数 hInstance, 整数型
.参数 lpParam, 整数型
.局部变量 句柄

集_HOOK.停止 ()
句柄 ＝ CreateWindowEx (dwExStyle, lpClassName, lpWindowName, dwStyle, x, y, nWidth, nHeight, hWndParent, hMenu, hInstance, lpParam)
.如果真 (lpClassName ≠ “EDIT”)
    返回 (句柄)
.如果真结束
SendMessage (句柄, 197, 2, 0)  ' 限制录入长度2
原窗口函数地址 ＝ SetWindowLong (句柄, -4, &回调函数)  ' 开始回调
集_HOOK.开始 ()
返回 (句柄)

.子程序 回调函数, 整数型
.参数 hwnd, 整数型
.参数 umsg, 整数型
.参数 wparam, 整数型
.参数 lparam, 整数型
.局部变量 返回值
.局部变量 长度

.判断开始 (umsg ＝ 258)  ' 字符录入
    .判断开始 (wparam ≥ 97 且 wparam ≤ 102)  ' a-f
        wparam ＝ wparam － 32  ' 转为大写
    .判断 (wparam ≥ 65 且 wparam ≤ 70)  ' A-F

    .判断 (wparam ≥ 48 且 wparam ≤ 57)  ' 0-9

    .判断 (wparam ＝ 8)  ' 退格键

    .判断 (wparam ＝ 9)  ' TAB键

    .判断 (wparam ＝ 13)  ' 回车键

    .默认
        返回 (0)  ' 限制其它录入
    .判断结束

.判断 (umsg ＝ 770)  ' 禁止粘贴5
    返回 (0)
.默认

.判断结束
返回值 ＝ CallWindowProc (原窗口函数地址, hwnd, umsg, wparam, lparam)
.如果真 (umsg ＝ 258 或 umsg ＝ 770)
    长度 ＝ SendMessage (hwnd, 14, 0, 0)
    .如果真 (长度 ＝ 2)
        PostMessage (hwnd, 258, 9, 0)
    .如果真结束

.如果真结束
返回 (返回值)

.子程序 _高级表格_将被编辑

集_HOOK.开始 ()

.子程序 _高级表格_结束编辑

集_HOOK.停止 ()

@风精灵