添加和修改易语言源码或模块密码功能

.版本 2
.支持库 dp1

.程序集 窗口程序集1

.子程序 __启动窗口_创建完毕



.子程序 修改易文件密码, 逻辑型
.参数 path, 文本型
.参数 raw_password, 文本型, 可空
.参数 new_password, 文本型, 可空
.局部变量 file
.局部变量 hdr1
.局部变量 hdr2
.局部变量 data, 字节集
.局部变量 ok, 逻辑型

file ＝ 打开加密文件 (path, #读入, , raw_password, 8)
.如果真 (file ≠ 0)
    读入数据 (file, hdr1)
    读入数据 (file, hdr2)
    .如果真 (hdr1 ＝ #Magic_加密源码)

        移动读写位置 (file, #现行位置, 32)
        ' 调试输出 (到文本 (读入字节集 (file, 32)), 倒转Hex文本 (取数据摘要 (到字节集 (raw_password))))
        读入数据 (file, hdr1)
        读入数据 (file, hdr2)
    .如果真结束
    .如果真 (hdr1 ＝ #Magic_文件标志1 且 hdr2 ＝ #Magic_文件标志2)
        data ＝ 读入字节集 (file, 取文件长度 (file))
        关闭文件 (file)
        file ＝ 打开加密文件 (path, #改写, , new_password, 8)
        .如果真 (new_password ≠ “”)
            写出数据 (file, #Magic_加密源码)
            写出数据 (file, 1)
            写出字节集 (file, EncodeKey (new_password))  ' 不可用[写出数据]
        .如果真结束
        写出数据 (file, #Magic_文件标志1)
        写出数据 (file, #Magic_文件标志2)
        写出字节集 (file, data)  ' 不可用[写出数据]
        ok ＝ 真
    .如果真结束
    关闭文件 (file)
.如果真结束
返回 (ok)

.子程序 EncodeKey, 字节集
.参数 key, 文本型

返回 (到字节集 (倒转Hex文本 (取数据摘要 (到字节集 (key)))))

.子程序 倒转Hex文本, 文本型
.参数 txt, 文本型
.局部变量 i, 整数型
.局部变量 result, 文本型
.局部变量 len

len ＝ 取文本长度 (txt)
.变量循环首 (1, len, 2, i)
    result ＝ result ＋ 取文本中间 (txt, len － i, 2)
.变量循环尾 ()
返回 (result)

.子程序 _按钮1_被单击

.如果 (修改易文件密码 (编辑框_path.内容, 编辑框_raw.内容, 编辑框_new.内容))
    信息框 (“ok”, #信息图标, )
.否则
    信息框 (“error!”, #错误图标, )
.如果结束


.子程序 _按钮2_被单击

.如果真 (通用对话框1.打开 ())
    编辑框_path.内容 ＝ 通用对话框1.文件名
.如果真结束

@royatai