易语言复制GIF动态图片到剪辑板源码

易语言复制GIF动态图片到剪辑板源码

@雨落无声

.版本 2

.程序集 窗口程序集1

.子程序 _按钮1_被单击
.局部变量 File, 文本型

File ＝ 通用对话框 (取窗口句柄 (), “图像文件|*.bmp;*.jpg;*.gif”, 0, 取运行目录 ())
输出调试文本 (File)
复制图像到剪辑板 (File)

.子程序 复制图像到剪辑板, 逻辑型, , 支持常见图像格式(*.bmp;*.jpg;*.gif)
.参数 图像路径, 文本型
.局部变量 html, 文本型
.局部变量 img, 对象
.局部变量 dom, 对象
.局部变量 rang, 对象

html ＝ 子文本替换 (#常量1, “[&GifFileName]”, 图像路径, , , 真)
dom.创建 (“{25336920-03F9-11CF-8FD0-00AA00686F13}”, )
dom.方法 (“write”, html)
rang ＝ dom.读对象型属性 (“body”, ).对象型方法 (“createControlRange”, )
img ＝ dom.对象型方法 (“getElementById”, “img”)
rang.方法 (“add”, img)
返回 (rang.逻辑方法 (“execCommand”, “copy”, 假, 0))

.子程序 通用对话框, 文本型
.参数 窗口句柄, 整数型
.参数 过滤器, 文本型
.参数 方式, 整数型, 可空, 0,打开文件 1,保存文件
.参数 初始目录, 文本型, 可空
.局部变量 File, OPENFILENAME
.局部变量 ret, 整数型
.局部变量 FilterArr, 文本型, , "0"
.局部变量 DefFilter, 文本型

File.lStructSize ＝ LocalSize (File)
File.hwndOwner ＝ 窗口句柄
File.hInstance ＝ GetModuleHandle (0)
File.lpstrFilter ＝ 子字节集替换 (到字节集 (过滤器), { 124 }, { 0 }, , ) ＋ { 0 } ＋ { 0 }
File.lpstrFile ＝ 取空白文本 (255)
File.nMaxFile ＝ 256
File.lpstrFileTitle ＝ 取空白文本 (255)
File.nMaxFileTitle ＝ 256
File.lpstrInitialDir ＝ 初始目录
File.lpstrTitle ＝ 选择 (方式 ＝ 0, “打开文件”, “保存文件”)
File.flags ＝ 0

.判断开始 (方式 ＝ 0)
    ret ＝ GetOpenFileNameA (File)
.默认
    ret ＝ GetSaveFileNameA (File)
    ' ------------------------------------------
    FilterArr ＝ 分割文本 (过滤器, “|”, )
    DefFilter ＝ FilterArr [File.nFilterIndex × 2]
    DefFilter ＝ 取文本右边 (DefFilter, 取文本长度 (DefFilter) － 1)
    .如果真 (File.lpstrFile ≠ DefFilter 且 DefFilter ≠ “.*”)
        File.lpstrFile ＝ File.lpstrFile ＋ DefFilter
    .如果真结束

.判断结束
.如果真 (ret ≠ 0)
    返回 (File.lpstrFile)
.如果真结束
返回 (“”)


.子程序 __启动窗口_创建完毕